Test Card Guide

1. Install the Java tools, once per PC.
2. Build and install with the kit: a menu does it all.
3. Or by hand: the javac, converter and gp.jar commands.
4. Test the card at a terminal.
5. When something goes wrong.

You need a supported JCOP card (J3R180, J3R150, J2A040), a contact PC/SC reader and a Windows 10 or 11 PC. The card data and the applets come from Card Data and Applet.

• The JDK must be 8: newer JDKs make class files the Java Card converter refuses. JDK 8 and Java 21 sit side by side without conflict.
• The Java Card 2.2.2 download has its bin and lib folders inside a second zip, java_card_kit-2_2_2-rr-bin-windows-do.zip: unzip it where it is.
• A PC that only installs cards someone else built needs just Java 11+ and gp.jar.

These tools come from their publishers, under their own licences; the site does not redistribute them. Versions checked on 2026-10-25.

1. Download the kit on the Kit page: pick your chip, and the cards ticked on the Applet page go in it.
2. Unzip it (right-click, Extract all). It does not run from inside the zip, needs no administrator rights and installs nothing.
3. Double-click START.cmd. Windows may ask whether to run a file from the internet: choose Run. A menu opens:

    KABC Test Card Kit - 3 cards for JCOP 4 (J3R180)
    ------------------------------------------------
     1  Check my setup          Java tools, reader, card
     2  Build the CAP files     javac and the Java Card converter
     3  Install on the card     replaces our applets if already there
     4  List the card           what is installed, and free memory
     5  Remove our applets      only the ones this kit installed
     6  Wipe the card           everything except the security domain
     0  Exit

4. 1 Check my setup finds the Java tools, the reader and the card, and says how to fix what is missing. What it finds is saved in card.env.
5. 2 Build, then 3 Install. Each step ends in a green Done or a red Stopped with what to do; the full output is in logs\.

Before installing, look at card.env. Its card key is the well-known default test key; if your card uses another, put it there. The website never asks for it.

# Your card and reader. This file stays on your PC.
chip=j3r180
reader=                 # part of the reader's name; empty = the only contact reader
key=404142434445464748494A4B4C4D4E4F   # the default test key
#key-enc=  key-mac=  key-dek=          # or three separate keys

# Your Java tools: found by Check my setup, or set here.
jdk8=
java=
gp-jar=
jc-kit=

What the kit runs, written out for a Command Prompt opened in the unzipped projects download. Repeat it for each project, including the PSE and the PPSE; the shared library is loaded once per card.

J3R180: NXP JCOP 4 (P71), newer mask, Java Card 3.0.5 Classic. Converter com.sun.javacard.converter.Main, javac -source 1.7, API api_classic.jar, and -Djc.home.

Build

rem Your tools: change these two lines to the folders on your PC
set "JDK8=C:\Program Files\Eclipse Adoptium\jdk-8.0.504.1-hotspot"
set "JC=C:\Program Files (x86)\Oracle\Java Card Development Kit 3.0.5u4"

rem Where this build goes (run the commands from the unzipped download)
set "OUT=%TEMP%\tc-build\TestCardInteracDebit"
rmdir /s /q "%OUT%" 2>nul & mkdir "%OUT%"

rem 1. Compile the shared library and the applet together, for Java Card 3.0.5 Classic (class files for Java 1.7)
"%JDK8%\bin\javac" -source 1.7 -target 1.7 -encoding UTF-8 -nowarn -Xlint:-options -cp "%JC%\lib\api_classic.jar" -d "%OUT%" lib\EmvCommonLib\src\com\testcard\emv\common\*.java projects\TestCardInteracDebit\src\com\testcard\emv\interacdebit\*.java

rem 2. Convert the library first: the applet links against its export file
"%JDK8%\bin\java" "-Djc.home=%JC%" -cp "%JC%\lib\api_classic.jar;%JC%\lib\*" com.sun.javacard.converter.Main -classdir "%OUT%" -d "%OUT%" -exportpath "%JC%\api_export_files" -out CAP EXP JCA com.testcard.emv.common 0xA0:0x00:0x00:0x02:0x03:0x02:0x00 1.0

rem 3. Convert the applet
"%JDK8%\bin\java" "-Djc.home=%JC%" -cp "%JC%\lib\api_classic.jar;%JC%\lib\*" com.sun.javacard.converter.Main -classdir "%OUT%" -d "%OUT%" -exportpath "%JC%\api_export_files;%OUT%" -applet 0xA0:0x00:0x00:0x02:0x77:0x10:0x10 com.testcard.emv.interacdebit.InteracDebitApplet -out CAP EXP JCA com.testcard.emv.interacdebit 0xA0:0x00:0x00:0x02:0x77:0x10:0x10:0x00 1.0

rem The CAP files:
rem   %OUT%\com\testcard\emv\common\javacard\common.cap
rem   %OUT%\com\testcard\emv\interacdebit\javacard\interacdebit.cap

Install

rem Java 11 or later runs gp.jar (not JDK 8). Change these lines to your files.
set "JAVA=C:\Program Files\Eclipse Adoptium\jre-21.0.12.1-hotspot\bin\java.exe"
set "GP=%USERPROFILE%\Downloads\gp.jar"
rem The card's key. This is the well-known default test key: use your card's own if it differs.
set KEY=404142434445464748494A4B4C4D4E4F

rem 1. See what is on the card (and that the key is right)
"%JAVA%" -jar "%GP%" --key %KEY% --list
rem    "Failed to open secure channel" or "Card cryptogram invalid": STOP. Fix the key first:
rem    every failed try counts down the card's lock counter, and at zero the card is locked for good.

rem 2. Load the shared library, once per card (skip it when the list shows A0000002030200)
"%JAVA%" -jar "%GP%" --key %KEY% --load "%OUT%\com\testcard\emv\common\javacard\common.cap"

rem 3. Remove an older copy of this applet (an error here on a fresh card is fine)
"%JAVA%" -jar "%GP%" --key %KEY% --delete A000000277101000 --force

rem 4. Load and install the applet
"%JAVA%" -jar "%GP%" --key %KEY% --install "%OUT%\com\testcard\emv\interacdebit\javacard\interacdebit.cap"
"%JAVA%" -jar "%GP%" --key %KEY% --list

Install deletes the old package with --force, which also removes its applet instance. The library stays: deleting it would remove every applet that links against it. To start again from an empty card, use the kit's Wipe, which keeps the security domain.

1. Load the CA key. terminal-ca-keys.txt, in the kit and in the projects download, has each CA public key your cards use: RID, index, modulus, exponent and checksum. Load it into the test terminal's CA key table. Without it, offline data authentication fails.
2. Run a purchase with the card in the contact slot, then tapped if your chip and reader are contactless. The PSE answers on contact and the PPSE on contactless.
3. Read the result. The terminal's receipt or log shows the TVR and the cryptogram. For a trace, the Trace Analyzer checks it rule by rule; the EMV Simulator runs the same flow step by step.

The card's PIN is in its profile (step 1 of Card Data). The cryptograms use the issuer master keys of step 2, so a test host with the same keys can check the ARQC and send an ARPC.